# Doc Hollywood AVS

# 'Doc Hollywood' is 104 minutes, and takes up two laserdisc sides, resulting
# in two capture files.  Both of these captures are used to create the final
# AVI.
AVISource("e:\Scratch Space\DH1.avi") ++ AVISource("e:\Scratch Space\DH2.avi")

# These frames must be manipulated to preserve the telecine pattern:
# 34266 repeat twice (three times total)
# 68190 delete this frame
# 84953 repeat this frame
# 87787 delete this frame
# 87788 delete this frame
# 89149 repeat this frame
# 89150 repeat this frame
# 99097 repeat this frame
# 101046 delete this frame
# there's a glitch at 101826, but it instantly corrects itself
# 101941 repeat this frame
# 107861 delete this frame
# 107862 delete this frame
# 112620 repeat this frame
# 112621 repeat this frame
# 130315 repeat twice (three times total)
# 156014 delete this frame
# 156015 delete this frame
#
# Note:  AVISynth does not have "soft" line breaks, so it is necessary for all
# this to be on a single line:
Trim(0,34266) ++ Trim(34266,34266) ++ Trim(34266,68189) ++ Trim(68191,84953) ++ Trim(84953,87786) ++ Trim(87789,89149) ++ Trim(89149,89150) ++ Trim(89150,99097) ++ Trim(99097,101045) ++ Trim(101047,101941) ++ Trim(101941,107860) ++ Trim(107863,112620) ++ Trim(112620,112621) ++ Trim(112621,130315) ++ Trim(130315,130315) ++ Trim(130315,156013) ++ Trim(156016,0)

# 'Doc Hollywood' on laserdisc is actually windowboxed, not letterboxed.  This
# means black borders appear on all four sides, not just the top and bottom.
#
# Most conventional televisions use "overscan," which basically means there
# is more to the picture than what is actually being shown on screen.
# Windowboxing is sometimes used to compensate for overscan, so that more of
# the original picture can be seen.  In the case of 'Doc Hollywood', the
# windowboxing bars are thicker on the top and bottom than on the sides, so the
# side borders are usually hidden from view thanks to overscan, while the top
# and bottom borders are still visible, creating the familiar letterboxed
# effect.
#
# This command crops the windowboxing entirely, even on the sides.
Crop(12,67,616,334)

# Visual noise filtering.
TemporalSoften(7,4,8,15,2)

# Untelecine.
Doubleweave()
Pulldown(0,2)

# To figure out how to make Pulldown match the telecine pattern, define five
# clips, each one using one of the five possible Pulldown routines.  Then, stack
# these five clips on top of each other to compare them, using StackVertical.
# To make sure the resulting picture isn't too big, crop each individual picture
# down to its first 100 rows of pixels:
# a = Crop(0,0,640,100).Pulldown(0,2)
# b = Crop(0,0,640,100).Pulldown(0,3)
# c = Crop(0,0,640,100).Pulldown(1,3)
# d = Crop(0,0,640,100).Pulldown(1,4)
# e = Crop(0,0,640,100).Pulldown(2,4)
# StackVertical(a,b,c,d,e)
#
# Next, save the AVS script and open it in VirtualDub or other player capable
# of examining AVIs frame by frame.  When advancing the movie by single frames,
# two of the five pictures will look alright.  The rest will show frames that
# are still mixed together.  Either of the two successful Pulldowns can be used.

# Removing the windowboxing gave the picture a rather exotic resolution.  The
# BicubicResize command is used to zoom the picture back out to 640 pixels
# across, and also 360 pixels down (both numbers are multiples of 8).
BicubicResize(640,360,0,0.5)