# Star Wars (disc 1) AVS

AVISource("e:\Scratch Space\SW1.avi") ++ AVISource("e:\Scratch Space\SW2.avi")

# Star Wars is 121 minutes long.  Each of its three laserdisc sides holds about 40
# minutes.  I have split the movie into two parts, to better preserve quality.  Each
# will hold about 60 minutes.  The split is right before where the Millenium Falcon
# comes out of hyperspace to find Alderaan is not there anymore.
Trim(0,109139)

# Manipulate these frames to preserve the telecine pattern.
# 12117 repeat this frame.
Trim(0,12117) ++ Trim(12117,0)

# The first half of Star Wars has some subtitles, and the engineers who mastered the
# laserdisc were very clever in putting the subtitles below the movie picture, in the
# bottom letterboxing bar.  However, that means the bottom letterboxing bar, or at
# least part of it, cannot be cropped, or those subtitles would be lost.
# Consequently, part of the top letterboxing bar should be left intact as well, to
# keep the picture centered.  Remember that the final resolution should be in
# multiples of 8 for best results.
Crop(0,65,640,352)

# The rest of the top letterboxing bar can be masked.
Crop(0,38,640,314).AddBorders(0,38,0,0)

# The remainder of the bottom letterboxing bar can be masked everywhere except during
# the subtitles, which are in only one scene (Han Solo talks to Greedo).
a = Trim(0,88321).Crop(0,0,640,314).AddBorders(0,0,0,38)
b = Trim(88322,89910)
c = Trim(89910,0).Crop(0,0,640,314).AddBorders(0,0,0,38)
a + b + c

# A small amount of visual noise filtering.
TemporalSoften(5,3,6)

# Untelecine.
DoubleWeave().Pulldown(0,2)

# To determine where the telecine pattern is, I create a picture using all five
# possible versions of the Pulldown function on the picture, and then stack them on
# top of each other.  To make sure the picture doesn't go off the screen, I use only
# the first 100 pixels of the picture, like so:
# d = Crop(0,0,640,100).Pulldown(0,2)
# e = Crop(0,0,640,100).Pulldown(0,3)
# f = Crop(0,0,640,100).Pulldown(1,3)
# g = Crop(0,0,640,100).Pulldown(1,4)
# h = Crop(0,0,640,100).Pulldown(2,4)
# StackVertical(d,e,f,g,h)
#
# Then, I play the picture frame by frame.  There will be two versions of the Pulldown
# routine that work.  The rest will show frames that are still mixed together.