# The Last Unicorn AVS - SVCD #1

# The first SVCD comes directly from the first capture.
AVISource("e:\Scratch Space\TLU1.avi")

# Manipulate these frames to preserve telecine pattern
# 31263 delete this frame
# 50123 repeat this frame \ I normally ignore these one-frame hiccups, but
# 50124 delete this frame / for the tricks I'm doing below, it's necessary.
# 57009 repeat this frame
# 57010 repeat this frame
# 64797 repeat this frame
Trim(0,31262) ++ Trim(31264,50123) ++ Trim(50123,50123) ++ Trim(50125,57009) ++ Trim(57009,57010) ++ Trim(57010, 64797) ++ Trim(64797,0)

# This is necessary for the un-telecining code below to work
AssumeFrameBased.ComplementParity

# Some noise filtering
TemporalSoften(5,3,6)

# Un-telecine
DoubleWeave()
Pulldown(1,3)

# The laserdisc was very badly mastered.  The film frame is never properly aligned,
# and the alignment changes often.  I am matting (artificially letterboxing) the
# entire movie to get rid of the border artifacts.  The amount of matting used depends
# on each scene of the movie.  Also, the opening credits were stretched vertically;
# I'm resizing and letterboxing them.  These frame numbers are not from the same set
# as those used for trimming, now that the movie has been un-telecined.
a = Trim(0,3208).Crop(0,8,640,464).AddBorders(0,8,0,8)
b = Trim(3209,3528).Crop(0,0,640,464).AddBorders(0,8,0,8)
c = Trim(3529,3644).Crop(0,16,640,440).AddBorders(0,16,0,24)
d = Trim(3645,3817).Crop(0,8,640,464).AddBorders(0,8,0,8)
e = Trim(3818,4167).Crop(0,8,640,464).BicubicResize(640,368,0,0.5).AddBorders(0,56,0,56)
f = Trim(4168,7469).Crop(16,24,600,432).BiCubicResize(640,368,0,0.5).AddBorders(0,56,0,56)
g = Trim(7470,26962).Crop(0,8,640,464).AddBorders(0,8,0,8)
h = Trim(26963,29652).Crop(0,0,640,464).AddBorders(0,8,0,8)
i = Trim(29653,30453).Crop(0,8,640,464).AddBorders(0,8,0,8)
j = Trim(30454,30702).Crop(0,0,640,464).AddBorders(0,8,0,8)
k = Trim(30703,34620).Crop(0,8,640,464).AddBorders(0,8,0,8)
l = Trim(34621,34716).Crop(0,16,640,440).AddBorders(0,16,0,24)
m = Trim(34717,40098).Crop(0,8,640,464).AddBorders(0,8,0,8)
n = Trim(40099,40140).Crop(0,0,640,448).AddBorders(0,8,0,8)
o = Trim(40141,43180).Crop(0,0,640,464).AddBorders(0,8,0,8)
p = Trim(43181,43214).Crop(0,8,640,440).AddBorders(0,16,0,24)
q = Trim(43215,0).Crop(0,8,640,464).AddBorders(0,8,0,8)

a + b + c + d + e + f + g + h + i + j + k + l + m + n + o + p + q